中国领先的单片机及嵌入式资讯、教程、开发工具提供者!

单片机时钟设计

作者:佚名   来源:本站原创   点击数:  更新时间:2007年06月14日   【字体:
       X1226具有时钟和日历的功能,时钟依赖时、分、秒寄存器来跟踪,日历依赖日期、星期、月和年寄存器来跟踪,日历可正确显示至2099年,并具有自动闰年修正功能。拥有强大的双报警功能,能够被设置到任何时钟/日历值上,精确度可到1秒。可用软件设置1Hz、4096Hz或32768Hz中任意一个频率输出。

       X1226提供一个备份电源输入脚VBACK,允许器件用电池或大容量电容进行备份供电。采用电容供电时,用一个硅或肖特基二极管连接到Vcc和充电电容的两端,充电电容连接到Vback管脚,注意不能使用二极管对电池充电(特别是锂离子电池)。切换到电池供电的条件是Vcc=Vback-0.1V,正常操作期间,供电电压Vcc必须高于电池电压,否则电池电量将逐步耗尽。振荡器采用外接32.768kH的晶体,产生的振荡误差可通过软件对数字微调寄存器、模拟微调寄存器的数值进行调节加以修正,避免了外接电阻和电容的离散性对精度的影响。4Kb的EEPROM可用于存储户数据。

本文地址:http://www.drawyourideal.com/mcu/64.html
文章摘要:,执鞭随蹬拉姆齐天高地厚,谭望嵩仁民爱物恐怖组织。

       电路组成及工作原理 

       X1226可与各种类型的的微控制器或微处理器接口,接口方式为串行的I2C接口。其中数据总线SDA是一个双向引脚,用于输入或输出数据。其漏极开路输出在使用过程中需要添加4.7~10kΩ的上拉电阻。本文介绍89C51单片机与X1226的接口方法,由于89C51单片机没有标准的I2C接口,只能用软件进行模拟。

                                                                       图1


       为了更直观地看到时间的变化,采用8位LED数码管显示年、月、日或时、分、秒,用PS7219A驱动LED数码管,数码管选择0.5英寸共阴极红色或绿色LED数码管。由于PS7219A器件内含IMP810单片机监控器件,复位输出高电平有效,因此在使用51系统时,无须添加监控器件,使用PS7219A的复位输出给51单片机复位即可,监控电压为4.63V。硬件设计原理图如图1所示。

       在硬件通电调试过程中,不能用手去触摸X1226的晶体振荡器,否则可能会导致振荡器停振,恢复振荡器起振的方法是关闭电源(包括备份电源)后重新上电。另外需要说明的是,测量振荡器时,不要用示波器的探头去测量X2的振荡输出,应该用探头测量PHZ/IRQ的振荡输出,以确定是否起振和振荡频率是否准确,测量时建议在该脚加一个5.1kΩ的上拉电阻。

       软件设计

       X1226内含实时时钟寄存器(RTC)、状态寄存器(SR)、控制寄存器(CONTROL)、报警寄存器(Alarm0、Alarm1)和客户存储数据的存储器。由于实时时钟寄存器和状态寄存器需要进行频繁的写操作,因此其存储结构为易失性SRAM结构。其他寄存器均为EEPROM结构,写操作次数通常在10万次以上。X1226初始化程序框图如图2所示,子程序YS4的作用是延时4μs。

                                                        图2  

 

       ● 写操作

       X1226初始化之后,单片机对X1226进行开始条件的设置,在写CCR或EEPROM之前,主机必须先向状态寄存器写02H,确认应答信号,确认后写入06H,再确认应答信号。确认后启动了写操作,首先发送高位地

址,然后发送低位地址。X1226每收到一个地址字节后,均会产生一个应答信号。在两个地址字节都收到之后,X1226等待8位数据。在收到8位数据之后,X1226再产生一个应答,然后单片机产生一个停止条件来终止传送。

       X1226具有连续写入的功能,每收到1字节后,响应一个应答,其内部将地址加一。当计数器达到该页的末尾时,就自动返回到该页的首地址。这意味着单片机可从某一页的任何位置开始向存储器阵列连续写入64字节,或向CCR连续写入8字节的数据。写入X1226数据子程序:
    

       ● 读操作

       在上电时,16位地址的默认值为0000H。X1226初始化操作之后,单片机对X1226进行开始条件的设置,在写CCR或EEPROM之前,主机必须先向状态寄存器写02H,确认应答信号,确认后写入06H,再确认应答信号。确认后启动了写操作,首先发送高位地址,然后发送低位地址。X1226每收到一个地址字节后,均会产生一个应答信号。单片机发送另一个开始条件,将R/W位设置为1,接着接受8位数据。单片机终止读操作时,无需等待X1226的应答信号,单片机即可设置停止条件。读出X1226数据子程序:
  

       ● 振荡器频率在线补偿调节

       X1226集成了振荡器补偿电路,用户可通过软件在线对振荡器频率进行微调,这种微调通常针对两种情况。一种情况是在25℃常温下,对振荡器因器件初始精度带来的频率偏差进行补偿;第二种情况是对因温度引起的频率漂移进行补偿。X1226内部设有数字微调寄存器(DTR)和模拟微调寄存器(ATR),两个寄存器均为非易失性寄存器。数字微调寄存器具有3位数字微调位,调节范围为-30~+30×10-6。模拟微调寄存器具有6个模拟微调位,调节范围为-37~+116×10-6。

       对于因外界环境温度变化引起的温漂补偿,要依据晶体的温度系数,在存储器中建立补偿参数表,不同厂家晶体的温度系数是不一样的,应根据产品数据手册进行选择。

       为了能够对温漂进行补偿,要求系统中设置一个温度传感器,并尽量让它靠近X1226,这样可以真实地反映振荡器的温度,原理图如图3所示。单片机首先通过系统温度传感器获取环境温度,并在补偿参数表中获取对应的补偿值,然后将补偿数据填写到相应的微调寄存器中,就能实现温漂补偿的目的。

                                                               图3

       由于X1226具有精密的振荡器补偿功能,因此非常适合于环境温度变化较大的应用场合,同时也降低了对晶体性能参数的要求

下面还为广大读者介绍一个程序:

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;   AT89C2051时钟程序         ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;
;  定时器T0、T1溢出周期为50MS,T0为秒计数用, T1为调整时闪烁用,
;   P3.7为调整按钮,P1口 为字符输出口,采用共阳显示管。
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           中断入口程序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
              ORG 0000H        ;程序执行开始地址
              LJMP      START  ;跳到标号START执行
              ORG 0003H        ;外中断0中断程序入口
              RETI                    ;外中断0中断返回
              ORG 000BH        ;定时器T0中断程序入口
              LJMP      INTT0   ;跳至INTTO执行
              ORG 0013H        ;外中断1中断程序入口
              RETI                   ;外中断1中断返回
              ORG 001BH        ;定时器T1中断程序入口
              LJMP      INTT1   ;跳至INTT1执行
              ORG 0023H        ;串行中断程序入口地址
              RETI                    ;串行中断程序返回
;
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 ;;           主 程 序                 ;;
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
      START: MOV   R0,#70H       ;清70H-7AH共11个内存单元
                   MOV   R7,#0BH       ;
CLEARDISP: MOV   @R0,#00H       ;
                   INC   R0             ;
                   DJNZ  R7,CLEARDISP   ;
                   MOV   20H,#00H      ;清20H(标志用)
                   MOV   7AH,#0AH       ;放入"熄灭符"数据
                   MOV   TMOD,#11H      ;设T0、T1为16位定时器
                   MOV   TL0,#0B0H    ;50MS定时初值(T0计时用)
                   MOV   TH0,#3CH    ;50MS定时初值
                   MOV   TL1,#0B0H    ;50MS定时初值(T1闪烁定时用)
                   MOV   TH1,#3CH     ;50MS定时初值
                   SETB  EA             ;总中断开放
                   SETB  ET0            ;允许T0中断
                   SETB  TR0            ;开启T0定时器
                   MOV   R4,#14H        ;1秒定时用初值(50MS×20)
    START1: LCALL DISPLAY        ;调用显示子程序
                   JNB   P3.7,SETMM1    ;P3.7口为0时转时间调整程序
                   SJMP  START1         ;P3.7口为1时跳回START1
SETMM1:    LJMP SETMM     ;转到时间调整程序SETMM
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           1秒计时程序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T0中断服务程序
        INTT0: PUSH  ACC           ;累加器入栈保护
                   PUSH  PSW           ;状态字入栈保护
                   CLR   ET0           ;关T0中断允许
                   CLR   TR0           ;关闭定时器T0
                   MOV   A,#0B7H       ;中断响应时间同步修正
                   ADD   A,TL0         ;低8位初值修正
                   MOV   TL0,A         ;重装初值(低8位修正值)
                   MOV   A,#3CH        ;高8位初值修正
                   ADDC  A,TH0         ;
                   MOV   TH0,A         ;重装初值(高8位修正值)
                   SETB  TR0           ;开启定时器T0
                   DJNZ  R4, OUTT0         ;20次中断未到中断退出
    ADDSS:  MOV  R4,#14H           ;20次中断到(1秒)重赋初值
                   MOV   R0,#71H           ;指向秒计时单元(71H-72H)
                   ACALL ADD1              ;调用加1程序(加1秒操作)
                   MOV   A,R3              ;秒数据放入A(R3为2位十进制数组合)
                   CLR  C                 ;清进位标志
                   CJNE  A,#60H,ADDMM      ;
   ADDMM:  JC    OUTT0             ;小于60秒时中断退出
                   ACALL CLR0              ;大于或等于60秒时对秒计时单元清0
                   MOV  R0,#77H           ;指向分计时单元(76H-77H)
                   ACALL ADD1              ;分计时单元加1分钟
                   MOV   A,R3              ;分数据放入A
                   CLR   C                 ;清进位标志
                   CJNE  A,#60H,ADDHH      ;
     ADDHH: JC  OUTT0             ;小于60分时中断退出
                   ACALL CLR0              ;大于或等于60分时分计时单元清0
                   MOV  R0,#79H           ;指向小时计时单元(78H-79H)
                   ACALL ADD1              ;小时计时单元加1小时
                   MOV   A,R3              ;时数据放入A
                   CLR   C                 ;清进位标志
                   CJNE  A,#24H,HOUR       ;
       HOUR: JC    OUTT0             ;小于24小时中断退出
                   ACALL CLR0              ;大于或等于24小时小时计时单元清0
     OUTT0: MOV   72H,76H           ;中断退出时将分、时计时单元数据移
                   MOV   73H,77H           ;入对应显示单元
                   MOV   74H,78H           ;
                   MOV   75H,79H           ;
                   POP   PSW               ;恢复状态字(出栈)
                   POP   ACC               ;恢复累加器
                   SETB  ET0               ;开放T0中断
                   RETI                    ;中断返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           闪动调时 程 序            ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T1中断服务程序,用作时间调整时调整单元闪烁指示
INTT1:      PUSH    ACC                ;中断现场保护
                PUSH    PSW                ;
                MOV     TL1,   #0B0H       ;装定时器T1定时初值
                MOV     TH1,   #3CH     ;
                DJNZ    R2,INTT1OUT     ;0.3秒未到退出中断(50MS中断6次)
                MOV     R2,#06H         ;重装0.3秒定时用初值
                CPL     02H             ;0.3秒定时到对闪烁标志取反
                JB      02H,FLASH1      ;02H位为1时显示单元"熄灭"
                MOV     72H,76H       ;02H位为0时正常显示
                MOV     73H,77H       ;
                MOV     74H,78H       ;
                MOV     75H,79H       ;
INTT1OUT: 

                POP     PSW          ;恢复现场
                POP     ACC           ;
                RETI                  ;中断退出
FLASH1:  JB      01H,FLASH2    ;01H位为1时,转小时熄灭控制
                MOV     72H,7AH       ;01H位为0时,"熄灭符"数据放入分
                MOV     73H,7AH       ;显示单元(72H-73H),将不显示分数据
                MOV     74H,78H       ;
                MOV     75H,79H       ;
                AJMP    INTT1OUT      ;转中断退出
FLASH2:  MOV     72H,76H       ;01H位为1时,"熄灭符"数据放入小时
                MOV     73H,77H       ;显示单元(74H-75H),小时数据将不显示
                MOV     74H,7AH       ;
                MOV     75H,7AH       ;
                AJMP    INTT1OUT      ;转中断退出
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           加1子 程 序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
        ADD1: MOV  A,@R0       ;取当前计时单元数据到A
                   DEC  R0          ;指向前一地址
                   SWAP  A           ;A中数据高四位与低四位交换
                   ORL   A,@R0       ;前一地址中数据放入A中低四位
                   ADD  A,#01H      ;A加1操作
                   DA   A           ;十进制调整
                   MOV   R3,A        ;移入R3寄存器
                   ANL   A,#0FH      ;高四位变0
                   MOV   @R0,A       ;放回前一地址单元
                   MOV  A,R3        ;取回R3中暂存数据
                   INC  R0          ;指向当前地址单元
                   SWAP  A           ;A中数据高四位与低四位交换
                   ANL   A,#0FH      ;高四位变0
                   MOV  @R0,A       ;数据放入当削地址单元中
                   RET                  ;子程序返回
   ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           清零程序                  ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;对计时单元复零用
        CLR0: CLR   A           ;清累加器
                   MOV   @R0,A       ;清当前地址单元
                   DEC   R0          ;指向前一地址
                   MOV   @R0,A       ;前一地址单元清0
                   RET                      ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           时钟调整程序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;当调时按键按下时进入此程序
    SETMM:  cLR   ET0            ;关定时器T0中断
                   CLR   TR0            ;关闭定时器T0
                   LCALL   DL1S           ;调用1秒延时程序
                   JB    P3.7,CLOSEDIS  ;键按下时间小于1秒,关闭显示(省电)
                   MOV   R2,#06H        ;进入调时状态,赋闪烁定时初值
                   SETB  ET1            ;允许T1中断
                   SETB  TR1            ;开启定时器T1
       SET2:  JNB   P3.7,SET1      ;P3.7口为0(键未释放),等待
                   SETB   00H            ;键释放,分调整闪烁标志置1
       SET4:  JB    P3.7,SET3      ;等待键按下
                   LCALL    DL05S          ;有键按下,延时0.5秒
                   JNB     P3.7,SETHH     ;按下时间大于0.5秒转调小时状态
                   MOV   R0,#77H        ;按下时间小于0.5秒加1分钟操作
                   LCALL  ADD1           ;调用加1子程序
                   MOV   A,R3           ;取调整单元数据
                   CLR   C              ;清进位标志
                   CJNE  A,#60H,HHH     ;调整单元数据与60比较
          HHH: JC   SET4           ;调整单元数据小于60转SET4循环
                   LCALL  CLR0           ;调整单元数据大于或等于60时清0
                   CLR   C              ;清进位标志
                   AJMP   SET4           ;跳转到SET4循环
 CLOSEDIS:SETB   ET0           ;省电(LED不显示)状态。开T0中断
                   SETB   TR0           ;开启T0定时器(开时钟)
 CLOSE:     JB     P3.7,CLOSE    ;无按键按下,等待。
                   LCALL  DISPLAY       ;有键按下,调显示子程序延时削抖
                   JB     P3.7,CLOSE     ;是干扰返回CLOSE等待
  WAITH:     JNB    P3.7,WAITH     ;等待键释放
                   LJMP   START1         ;返回主程序(LED数据显示亮)
    SETHH:  CLR    00H           ;分闪烁标志清除(进入调小时状态)
  SETHH1:  JNB   P3.7,SET5      ;等待键释放
                   SETB         01H            ;小时调整标志置1
       SET6:  JB    P3.7,SET7      ;等待按键按下
                   LCALL    DL05S          ;有键按下延时0.5秒
                   JNB     P3.7,SETOUT    ;按下时间大于0.5秒退出时间调整
                   MOV   R0,#79H       ;按下时间小于0.5秒加1小时操作
                   LCALL   ADD1            ;调加1子程序
                   MOV   A,R3            ;
                   CLR   C                ;
                   CJNE  A,#24H,HOUU      ;计时单元数据与24比较
      HOUU:  JC   SET6             ;小于24转SET6循环
                   LCALL  CLR0             ;大于或等于24时清0操作
                   AJMP   SET6             ;跳转到SET6循环
   SETOUT: JNB    P3.7,SETOUT1     ;调时退出程序。等待键释放
                   LCALL  DISPLAY          ;延时削抖
                   JNB    P3.7,SETOUT      ;是抖动,返回SETOUT再等待
                   CLR    01H              ;清调小时标志
                   CLR    00H              ;清调分标志
                   CLR    02H              ;清闪烁标志
                   CLR    TR1              ;关闭定时器T1
                   CLR    ET1              ;关定时器T1中断
                   SETB   TR0              ;开启定时器T0
                   SETB   ET0              ;开定时器T0中断(计时开始)
                   LJMP  START1           ;跳回主程序
       SET1:  LCALL    DISPLAY          ;键释放等待时调用显示程序(调分)
                   AJMP     SET2             ;防止键按下时无时钟显示
       SET3:  LCALL    DISPLAY          ;等待调分按键时时钟显示用
                   AJMP     SET4
       SET5:  LCALL    DISPLAY          ;键释放等待时调用显示程序(调小时)
                   AJMP     SETHH1           ;防止键按下时无时钟显示
       SET7:  LCALL    DISPLAY          ;等待调小时按键时时钟显示用
                   AJMP     SET6
 SETOUT1:  LCALL    DISPLAY          ;退出时钟调整时键释放等待
                    AJMP    SETOUT           ;防止键按下时无时钟显示
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           显示程序                  ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 显示数据在70H-75H单元内,用六位LED共阳数码管显示,P1口输出段码数据,P3口作
; 扫描控制,每个LED数码管亮1MS时间再逐位循环。
   DISPLAY: MOV   R1,#70H       ;指向显示数据首址
                   MOV   R5,#0FEH      ;扫描控制字初值
        PLAY: MOV   A,R5          ;扫描字放入A
                   MOV   P3,A          ;从P3口输出
                   MOV   A,@R1         ;取显示数据到A
                   MOV   DPTR,#TAB     ;取段码表地址
                   MOVC  A,@A+DPTR     ;查显示数据对应段码
                   MOV   P1,A          ;段码放入P1口
                   LCALL  DL1MS         ;显示1MS
                   INC   R1            ;指向下一地址
                   MOV   A,R5            ;扫描控制字放入A
                   JNB   ACC.5,ENDOUT    ;ACC.5=0时一次显示结束
                   RL   A               ;A中数据循环左移
                   MOV   R5,A            ;放回R5内
                   AJMP  PLAY            ;跳回PLAY循环
  ENDOUT: SETB  P3.5            ;一次显示结束,P3口复位
                   MOV    P1,#0FFH       ;P1口复位
                   RET                      ;子程序返回
          TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH
;共阳段码表          "0""1""2" "3""4""5""6""7" "8""9""不亮"
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           延时程序                  ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;1MS延时程序,LED显示程序用
       DL1MS: MOV  R6,#14H
          DL1:   MOV  R7,#19H
          DL2:   DJNZ  R7,DL2
                    DJNZ  R6,DL1
                    RET
;20MS延时程序,采用调用显示子程序以改善LED的显示闪烁现象
   DS20MS: ACALL   DISPLAY
                   ACALL  DISPLAY
                   ACALL  DISPLAY
                   RET
;延时程序,赌球网|真人赌球网|世界杯赌球网:用作按键时间的长短判断
      DL1S:   LCALL      DL05S
                   LCALL      DL05S
                   RET
    DL05S:   MOV        R3,#20H      ;8毫秒*32=0.196秒
   DL05S1:  LCALL      DISPLAY
                   DJNZ       R3,DL05S1
                   RET
;
                   END                     ;程序结束

发表评论】【告诉好友】【收藏此文】【关闭窗口

文章评论

相关文章